Excel

Macro Guidelines for Excel VBA Beginners

Ryan Van Slooten — Tue, 27 May 2008 23:28:20 GMT

I'm in the process of updating an Excel spreadsheet that is failing when it is running inside of Internet Explorer. The issue is related to the ActiveSheet and other global properties having a value of Nothing when the code is assuming they have valid references. As I am going through this spreadsheet, I am noting a wide variety of programming deficiencies and inefficiencies. Here is a list of some of the issues encountered:

If you run spreadsheets under Internet Explorer, use Application.ThisWorkbook and to ensure the browser evaluates the reference correctly.

NOTE: This is not an exhaustive list, nor do I claim that the "Better" examples are the best code example, but rather they are (hopefully) significant improvements over the "Bad" examples. In many cases, I have kept the design of the bad example so that you can see the differences however you should strive to completely refactor the code if possible.

Do not abuse the "With" statement in VBA.
Some people like "With" and some people don't and I don't particularly care for it. In particular, do not use nested "With" statements.
Example of Bad Code
```
' ... BAD EXAMPLE: DO NOT USE ...
With ActiveSheet
  With TestForm
    ' ...
  End With ' TestForm
End With ' ActiveSheet
' ... BAD EXAMPLE: DO NOT USE ...
```

Avoid using the "Goto" statement in VBA.

"Goto" is almost always a bad idea and a sign of spaghetti code. There are very few cases were it is appropriate to use it -- very few cases!

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
For i = iHere To lRealLastRow Step 2
  BuildStr = "A" & i + 1
  Range(BuildStr).Select
  If Range(BuildStr).Value = "---" Then GoTo DoneWithNames
  SelectItemDlg.Items_List.AddItem Range(BuildStr).Text
Next

DoneWithNames:
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code (I still would have designed it differently)

' ...
Dim MyCell As Range
For i = iHere To lRealLastRow Step 2
  Set MyCell = Cells(i + 1, 1)
  If MyCell.Value = "---" Then
    Exit For
  End If
  SelectItemDlg.Items_List.AddItem MyCell.Text
Next
' ...

Avoid using the name of a Form inside the Form code

The current form is implied in the code. It is not necessary to use the form name to reference controls on the form. If you want to differeniate form controls, you can use the 'Me' keyword such as: Me.Hide

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
' This example is doubly bad because it uses the form name (ChartConfig)
' both explicitly and in a With statement
If ChartConfig.Variable1.Text = ChartConfig.Variable2.Text Then
    MsgBox "Variable1 cannot be same as Variable2. Please choose another variable type.", vbOKCancel

    'Turn off the Change effect on Variable2.
    changeCasevar = False
    With ChartConfig
        .Variable2.Text = ""
        .Variable2Desc.Text = ""
        .Variable2Uom.Text = ""
    End With
    'Turn back on the Change effect on Variable2.
    changeCasevar = True
    Exit Sub
    '
End If

' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code (I still would have designed it differently)

' ...
If Variable1.Text = Variable2.Text Then
    MsgBox "Variable1 cannot be same as Variable2. Please choose another variable type.", vbOKCancel

    'Turn off the Change effect on Variable2.
    changeCasevar = False

    Variable2.Text = ""
    Variable2Desc.Text = ""
    Variable2Uom.Text = ""

    'Turn back on the Change effect on Variable2.
    changeCasevar = True
    Exit Sub
End If

Use Error Handling and Resume to restore Application.ScreenUpdating

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
' There are quite a few global variables and a pass-by-reference
' boolean that should just be the function return value.
Application.ScreenUpdating = False

iOption = "Single"
x = ChartPicker.Input_Val_Text
Call CheckUserRangeInputsAndOutputs(iOption, OkToChart)
iOption = ""

If OkToChart = True Then
    With ChartConfig
        CreateChartingArrays
    End With
End If

Application.ScreenUpdating = True
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code (I still would have designed it differently)

' ...
  On Error GoTo ErrorHandler

  Application.ScreenUpdating = False

  If CheckUserRangeInputsAndOutputs("Single") Then
    ChartConfig.CreateChartingArrays
  End If

Exit_Handler:
  Application.ScreenUpdating = True
  Exit Sub

ErrorHandler:
  MsgBox "Error " & Err.Number & ": " & Err.Description
  Resume Exit_Handler

Use If, Else If, and Else correctly.

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
If TextBoxMinimum.Text = "" Then
  MsgBox "Must enter Minimum Value before proceeding", vbOK
  Result = False
  Exit Function
End If

If TextBoxMaximum.Text = "" Then
  MsgBox "Must enter Maximum Value before proceeding", vbOK
  Result = False
  Exit Function
End If
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code

' ...
' For a explicit method, you can directly refer to the controls
Result = False
If Not IsNumeric(TextBoxMinimum.Text) Then
  MsgBox "Must enter Minimum Value before proceeding", vbOK
  TextBoxMinimum.SetFocus
ElseIf Not IsNumeric(TextBoxMaximum.Text) Then
  MsgBox "Must enter Maximum Value before proceeding", vbOK
  TextBoxMaximum.SetFocus
Else
  Result = True
End If

' If you can use a generic method, you can iterate through all of the controls
' There are obviously better ways of doing this, especially with .NET
Dim ValidateControl
Dim ControlList = Array(TextBox1, TextBox2, TextBox3)
For Each ValidateControl In ControlList
  If Input_Val_Text = Null Or Input_Val_Text = "" Then
    MsgBox "Must enter Value in " & ValidateControl.Name & " before proceeding", vbOK
    Result = False
    Exit Function
  End If
Next

Avoid using the ActiveSheet, Range, Cells, and other global variables.

Rather than assuming a position, it is much better to set a variable to the desired Workbook, Worksheet, or Range.

In particular, if there is any chance the spreadsheet might run under a browser, use Application.ThisWorkbook to ensure the browser evaluates the macro correctly.

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
'NOTE: Arrays start with 1st position as "0", not "1"
'Thus ColLtrs(0) is not used but placed there as a spacer for letter to column alignment:
ColLtrs = Array("", "A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z")

With ActiveSheet
  Range(ColLtrs(iOutCol) & iOutRow).Select
    
  If UnitSystem = "Metric" Then
    iRow = ActiveCell.Row
    For i = iRow To iLastRow - 1
      currCell = ColLtrs(ActiveCell.Column) & i + 1

      If Range(currCell).Value <> "" Then
        'capture the value from original calculatated data
        Range(currCell).Select

        strOrigValueCell = ColLtrs(iResultsCol) & ActiveCell.Row
        Result = ConvertUom(Range(strOrigValueCell))
      End If
    Next i
  End If
End With
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code

' ...
Dim mySheet As Worksheet
Dim Value As Variant

Set mySheet = ActiveSheet

For i = iRow To iLastRow - 1
  Value = mySheet.Cells(i, iOutCol).Value
  If Value <> "" Then
    Result = ConvertUom(UnitSystem, Value)
  End If
Next i

' To get a column letter/code, do not reinvent the wheel!
' Various functions from:
' http://www.dicks-blog.com/archives/2004/05/21/column-numbers-to-letters/

Function ColLetter(ColNumber As Long) As String
    On Error Resume Next
    ColLetter = Application.Substitute(Application.ConvertFormula("R1C" & ColNumber, xlR1C1, xlA1, 4), "1", "")
End Function

Function ColumnLetter(ByVal c As Long) As String
  Dim p As Long
  While c
    p = 1 + (c - 1) Mod 26
    c = (c - p) \ 26
    ColumnLetter = Chr$(64 + p) & ColumnLetter
  Wend
End Function

Avoid using .Select and moving selection in macros unless absolutely.

Do not change the current sheet or selection unless that is the intention of the macro. In general, don't mess with the user, flip sheets, or other heinous acts and try to leave things the way you found them.

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
For i = 1 To 10
  Range("A" & i).Select
  ActiveCell.Value = "Row " & i
Next i
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code

Dim iColumn As Long
Dim mySheet As Worksheet
Dim myRange As Range

iColumn = 1
Set mySheet = ActiveSheet

For iRow = 1 To 10
  Set rng = mySheet.Cells(iRow, iColumn)
  rng.Value = "Row " & iRow
Next iRow

Formatting XML in Excel/VB

Ryan Van Slooten — Wed, 23 May 2007 15:23:57 GMT

I was working on a spreadsheet that submitted XML data to a web service and the XML that was being generated by the XmlDocument object was not very tidy. Normally with C# I use Tidy.NET to clean up the HTML or XML, but since this was being used in Excel I didn't want to have any external dependencies. I found the following code online and it seems to work pretty well:

Option Explicit

' http://www.vb-helper.com/howto_formatted_xml_document.html
' Add formatting to the document.
Public Sub FormatXmlDocument(ByVal xml_doc As DOMDocument)
    FormatXmlNode xml_doc.documentElement, 0
End Sub

' Add formatting to this element. Indent it and add a
' carriage return before its children. Then recursively
' format the children with increased indentation.
Private Sub FormatXmlNode(ByVal node As IXMLDOMNode, _
                          ByVal indent As Integer)
Dim child As IXMLDOMNode
Dim text_only As Boolean

    ' Do nothing if this is a text node.
    If TypeOf node Is IXMLDOMText Then Exit Sub

    ' See if this node contains only text.
    text_only = True
    If node.hasChildNodes Then
        For Each child In node.childNodes
            If Not (TypeOf child Is IXMLDOMText) Then
                text_only = False
                Exit For
            End If
        Next child
    End If

    ' Process child nodes.
    If node.hasChildNodes Then
        ' Add a carriage return before the children.
        If Not text_only Then
            node.insertBefore _
                node.ownerDocument.createTextNode(vbCrLf), _
                node.FirstChild
        End If

        ' Format the children.
        For Each child In node.childNodes
            FormatXmlNode child, indent + 2
        Next child
    End If

    ' Format this element.
    If indent > 0 Then
        ' Indent before this element.
        node.parentNode.insertBefore _
            node.ownerDocument.createTextNode(Space$(indent)), _
            node

        ' Indent after the last child node.
        If Not text_only Then _
            node.appendChild _
                node.ownerDocument.createTextNode(Space$(indent))

        ' Add a carriage return after this node.
        If node.nextSibling Is Nothing Then
            node.parentNode.appendChild _
                node.ownerDocument.createTextNode(vbCrLf)
        Else
            node.parentNode.insertBefore _
                node.ownerDocument.createTextNode(vbCrLf), _
                node.nextSibling
        End If
    End If
End Sub

C# Utility to export Excel Worksheet As ADO Recordset XML

Ryan Van Slooten — Fri, 19 Jan 2007 13:52:36 GMT

I wrote a little VBA the other day to save an Excel Worksheet as an ADODB.Recordset XML file. I decided to see how hard it would be to do the exact same thing in C#. The idea is that I might start using C# Script instead of JavaScript for little utilities in the future.

using System;
using System.Collections.Generic;
using System.Data;
using System.Reflection;
using System.Runtime.InteropServices;

using ADODB;
using Excel;

namespace ExcelUtility
{
	class ExcelExport
	{
		public const string EXCEL_PROG_ID = "Excel.Application";

public static Excel.Application ExcelApplication
		{
			get
			{
				Excel.Application app = null;

try
				{
					// http://msmvps.com/blogs/pauldomag/archive/2006/03/15/86417.aspx
					app = Marshal.GetActiveObject(EXCEL_PROG_ID) as Excel.Application;
				}
				catch (Exception ex)
				{
					System.Diagnostics.Trace.WriteLine(ex.ToString());
				}

if (app == null)
				{
					try
					{
						app = new Excel.ApplicationClass();
					}
					catch (Exception ex)
					{
						System.Diagnostics.Trace.WriteLine(ex.ToString());
					}
				}

return app;
			}
		}

public static System.Data.DataTable SaveWorksheetAsDataTable()
		{
			Excel.Application app = ExcelApplication;
			Excel.Workbook book = app.ActiveWorkbook as Excel.Workbook;
			Excel.Worksheet sheet = app.ActiveSheet as Excel.Worksheet;
			int col, colcount;
			int row, rowcount;

if (sheet == null)
				return null;

// Get the current sheet range
			Excel.Range range = sheet.Cells;
			colcount = sheet.UsedRange.Columns.Count;
			rowcount = sheet.UsedRange.Rows.Count;

// Get the header row
			row = 1;
			System.Data.DataTable dt = new System.Data.DataTable(sheet.Name);
			for (col = 1; col <= colcount; ++col)
			{
				string text = (string)(range[row, col] as Excel.Range).Text;
				dt.Columns.Add(text, typeof(string));
			}

// Get all of the data
			for (row = 2; row <= rowcount; ++row)
			{
				DataRow dr = dt.NewRow();
				for (col = 0; col < colcount; ++col)
				{
					string text = (string)(range[row, col + 1] as Excel.Range).Text;
					if (text.Length > 0)
						dr[col] = text;
				}
				dt.Rows.Add(dr);
			}

// Save the data
			dt.WriteXml(book.Path + "\\" + sheet.Name + ".xml");

// Clean up
			app = null;
			return dt;
		}

public static ADODB.Recordset SaveWorksheetAsRecordset()
		{
			Excel.Application app = ExcelApplication;
			Excel.Worksheet sheet = app.ActiveSheet as Excel.Worksheet;
			int col, colcount;
			int row, rowcount;

if (sheet == null)
				return null;

// Get the current sheet range
			Excel.Range range = sheet.Cells;
			colcount = sheet.UsedRange.Columns.Count;
			rowcount = sheet.UsedRange.Rows.Count;

// Get the header row
			row = 1;
			ADODB.Recordset rst = new ADODB.RecordsetClass();
			for (col = 1; col <= colcount; ++col)
			{
				string text = (string)(range[row, col] as Excel.Range).Text;
				rst.Fields.Append(text, ADODB.DataTypeEnum.adVarChar, 255, ADODB.FieldAttributeEnum.adFldMayBeNull, null);
			}
			rst.Open(null, null, CursorTypeEnum.adOpenUnspecified, LockTypeEnum.adLockUnspecified, -1);

ADODB.Field[] fields = new ADODB.Field[colcount];
			for (col = 0; col < colcount; ++col)
				fields[col] = rst.Fields[col];

// Get all of the data
			for (row = 2; row <= rowcount; ++row)
			{
				rst.AddNew(null, null);
				for (col = 0; col < colcount; ++col)
				{
					string text = (string)(range[row, col + 1] as Excel.Range).Text;
					if (text.Length > 0)
						fields[col].Value = text;
				}
				rst.Update(null, null);
			}

// Save the data
			string filename = book.Path + "\\" + sheet.Name + ".xml";
			rst.Save(filename, PersistFormatEnum.adPersistXML);

// Clean up
			app = null;
			return dt;
		}
	}
}

Export Excel Worksheet to ADO Recordset

Ryan Van Slooten — Mon, 15 Jan 2007 18:22:28 GMT

This weekend I was working on a spreadsheet and I needed to save the data as a recordset. Unfortunately there didn't seem to be a way to do it easily without VBA macros. So I wrote this macro to save the current worksheet as an ADODB.Recordset XML file. Remember to add a reference to Microsoft.ActiveX Data Object 2.8 Library in the Excel Visual Basic Editor.

Public Sub CreateAdoRecordsetXml()
    Dim rst As New ADODB.Recordset
    Dim sheet As Worksheet
    Dim col As Long, colcount As Long
    Dim row As Long, rowcount As Long
    Dim Filename As String

Filename = ActiveWorkbook.Path + "\" + ActiveSheet.Name + ".xml"
    Set sheet = ActiveSheet
    colcount = sheet.UsedRange.Columns.count
    rowcount = sheet.UsedRange.Rows.count

col = 1
    row = 1
    Do While col <= colcount
        Call rst.Fields.Append(sheet.Cells(row, col).Text, adVarChar, 255, adFldMayBeNull)
        col = col + 1
    Loop
    rst.Open

row = 2
    Do While row <= rowcount
        col = 1
        Call rst.AddNew
        With rst.Fields
            Do While col <= colcount
                If sheet.Cells(row, col).Text <> "" Then
                    .Item(col - 1).Value = sheet.Cells(row, col).Text
                End If
                col = col + 1
            Loop
        End With
        Call rst.Update
        row = row + 1
    Loop

Call rst.Save(Filename, adPersistXML)
End Sub

Excel

Macro Guidelines for Excel VBA Beginners

Do not abuse the "With" statement in VBA.

Example of Bad Code

Avoid using the "Goto" statement in VBA.

Example of Bad Code

Example of Better Code (I still would have designed it differently)

Avoid using the name of a Form inside the Form code

Example of Bad Code

Example of Better Code (I still would have designed it differently)

Use Error Handling and Resume to restore Application.ScreenUpdating

Example of Bad Code

Example of Better Code (I still would have designed it differently)

Use If, Else If, and Else correctly.

Example of Bad Code

Example of Better Code

Avoid using the ActiveSheet, Range, Cells, and other global variables.

Example of Bad Code

Example of Better Code

Avoid using .Select and moving selection in macros unless absolutely.

Example of Bad Code

Example of Better Code

Formatting XML in Excel/VB

C# Utility to export Excel Worksheet As ADO Recordset XML

Export Excel Worksheet to ADO Recordset